OpenOffice.org vo výrobnej firme 7 – Objednávka 1

calc.png Ďalším dôležitým dokumentom vo vašom systéme je objednávka, a tú si dnes začnete tvoriť. Na začiatok krátky popis: tento dokument slúži na prijímanie zákaziek (objednávok) , tvorbu cenových ponúk a vytvorenie listu výroby. Po vyplnení dokumentu sa dáta exportujú do šablóny faktúra, číslo objednávky do šablóny objednávka.  

Tlačový výstup je buď objednávka, alebo cenová ponuka a tak isto aj export do pdf a list výroby, v ktorom sú uvedené jednotlivé výrobky a materiály, ktoré sa majú na ne použiť. Súbor sa potom uloží buď ako objednávka s číslom a názvom odberateľa, alebo ako ponuka tak isto s číslom a názvom odberateľa.

Príprava

Začnite ako obvykle otvorením prázdneho zošitu, ktorý si hneď môžete uložiť do priečinku Firma, ako objednávka.ods. Kto chce, ako pomôcku si môže stiahnuť šablónu tohto súboru: objednávka1.ods

Tento dokument je veľmi podobný dokumentu faktúra a keďže sú ovládacie prvky a formátovanie podobné ako v tomto dokumente, nebudem sa rozpisovať podrobne o ich vkladaní (nakoľko ste sa to už naučili). Takže by ste mali napredovať rýchlejšie.

Zošit obsahuje 11 listov, ktoré sú pomenované nasledovne: objednávka, list výroby, spotreba, export, kód, odberateľ, kalkulácia, cena, fakturanti, číslo objednávky, pdf. Vložte si listy a pomenujte presne tak ako v diele OpenOffice.org vo výrobnej firme 2 – Faktúra 1.

Funkčnosť

List objednávka slúži na prácu s dátami a hlavne na:

  • vloženie originálneho čísla objednávky /cenovej ponuky;
  • uloženie súboru pod týmto číslom + názvom odberateľa;
  • automatické zadanie adresy odberateľa;
  • automatické vloženie ceny a mj k vybratému tovaru;
  • výpočet ceny, zľavy, DPH a ostatných údajov potrebných k fakturácii aj so zaokrúhlením;
  • z listu export sú vy-exportované dáta do zošitu objednávky.ods, ktorý vám slúži ako databáza, a do šablóny faktúra.ots;
  • v tomto liste si taktiež môžete zistiť najnižšiu možnú predajnú cenu výrobku, najvyššiu zľavu ktorú môžete poskytnúť, váhu a plochu tovaru.

List výroby slúži pre zistenie množstva a duhu materiálu potrebného k výrobe pre jednotlivé výrobky a je na ňom aj celkový sumár materiálu. List spotreba je pomocný list pre list výroby. List export slúži samozrejme na export dát. Listy kalkulácia, cena, fakturanti a číslo objednávky sú listy s dátami. A nakoniec list pdf, slúži pre export do PDF a je z neho aj tlačový výstup objednávka/cenová ponuka.

Tvorba tabuľky objednávka

Začnite si postupne tvoriť tabuľku v liste objednávka. Keďže ste už tvorili dokument faktúra a podobnosť objednávky s dokumentom faktúra je veľká, nebude to už teraz pre vás žiadny problém.

Hlavička, telo tabuľky a pätka

Začnite vložením všetkých údajov, ktoré sa nebudú meniť, a tak isto si ju aj sformátujte (zlúčte bunky a urobte okraje) podľa nasledujúceho obrázku. Odberateľa aj s vložením ovládacieho prvku zoskupenie si vložte presne tak, ako ste si ho vložili v dokumente faktúra OpenOffice.org vo výrobnej firme 2 – Faktúra 1.

Ako ste si všimli, v hlavičke chýba dodávateľ, nakoľko v tomto dokumente je tlačový výstup z listu pdf a tento je uvedený v hlavičke strany. Doplníte ho tam neskôr až pri tvorbe tohto listu. Z toho istého dôvodu (tlačí sa list pdf) aj formátovanie tohto listu (objednávka) je len pre vašu potrebu (aby to vyzeralo prehľadne).

List objednávkaList objednávka

Vzorce

Budem uvádzať bunku, vzorec a popis.

C1=IF(M2="1";"Objednávka";"Cenová ponuka") – vypíše do hlavičky či je to objednávka, alebo cenová ponuka.

C4=IF(M2="1";IF(L1+1<10;"00"&L1+1;IF(L1+1<100;"0"&L1+1;L1+1));IF(L3+1<10;"00"&L3+1;IF(L3+1<100;"0"&L3+1;L3+1))) 

Pokiaľ je to objednávka, zistí číslo objednávky, ak je to cenová ponuka, zistí číslo cenovej ponuky.

C9=B57 – fakturant podľa toho, kto vystavil dokument.

F4 – vytvorte výberové pole, vyberte v menu Dáta | Platnosť... presne ako ste postupovali vo faktúre ( OpenOffice.org vo výrobnej firme 3 – Faktúra 2) a do zdroja zadajte $odberatel.$A$1:$A$498.

F5=VLOOKUP($F$4;$odberatel.$A$1:$B$498;2;FALSE()) - nájde adresu odberateľa.

F6=VLOOKUP($F$4;$odberatel.$A$1:$D$498;4;FALSE()) - nájde PSČ odberateľa.

G6=VLOOKUP($F$4;$odberatel.$A$1:$C$498;3;FALSE()) - nájde mesto odberateľa.

G7=VLOOKUP($F$4;$odberatel.$A$1:$E$498;5;FALSE()) - nájde IČO odberateľa.

G8=VLOOKUP($F$4;$odberatel.$A$1:$F$498;6;FALSE()) - nájde DRČ odberateľa.

F10=IF(SUM(K12:K51)>0;"Doplň predmet alebo množstvo";" ") - vypíše upozornenie pokiaľ nie je vyplnený tovar, alebo jeho množstvo.

A12=IF(D12<>0;1;" ") - prvé poradové číslo.

A13=IF(D13<>0;A12+1;" ") - ďalšie poradové číslo; tento vzorec si prekopírujte až po bunku A51.

B12=IF(ISNUMBER(J12);VLOOKUP(J12;$kód.$A$1:$B$1001;2;FALSE());" ") - nájde názov tovaru podľa kódu v bunke J12, pokiaľ je vypísaný. V tejto bunke si vytvorte aj výberové pole, vyberte v menu Dáta | Platnosť... do zdroja zadajte $kód.$B$2:$B$1001 .

C12=IF(AND(B12<>0;NOT(ISERROR(VLOOKUP(B12;$kód.$B$1:$C$1001;2;FALSE()))));VLOOKUP(B12;$kód.$B$2:$C$1001;2;FALSE());" ") 

Nájde cenu k tovaru, pokiaľ je vyplnený a pokiaľ ju má.

E12=IF(ISNUMBER(C12);VLOOKUP(B12;$kalkulácia.$A$1:$C$992;3;FALSE());" ") 

Nájde mernú jednotku tovaru.

F12=IF(AND(ISNUMBER(C12);ISNUMBER(D12));C12*D12;" ") 

Spočíta množstvo * cena.

H12=IF(ISNUMBER(C12);0,19;" ") - vypočíta 19% DPH.

I12=IF(AND($M$1;ISNUMBER(C12));$K$1/100;" ") - ukáže % zľavy, pokiaľ je zaškrtnuté políčko so zľavou ($M$1).

Teraz si označte bunky B12:I12 a prekopírujte vzorce až po riadok 51.

B54=IF(C5<>0;C5+30;" ") - platnosť objednávky/ponuky je dátum vystavenia + 30 dní.

B57 – vytvorte výberové pole, vyberte v menu Dáta | Platnosť... a do zdroja zadajte fakturanti.A2:A10 .

C59=SUM(U12:U51) – váha.

B60=IF(B54<TODAY();"NEPLATNÉ";"PLATNÉ") – platnosť.

C61=SUM(V13:V51) – plocha.

H52=SUM(F12:F51) – súčet.

H54=IF(N52<>0;N52*-1;" ") - zľava spolu.

H55=H52+H54 – spolu.

H56=ROUND(H55*0,19;2) – DPH.

H57=SUM(H55:H56) – spolu s DPH.

F54=IF(M1=TRUE();"zľava:";" ") - ukáže nápis „zľava“, pokiaľ je zľava použitá.

I11=IF(M1=TRUE();"zľava";" ") - ako v F54.

Teraz prejdete na pomocné vzorce.

K12=IF(OR(ISNUMBER(C12);ISNUMBER(D12));IF(AND(ISNUMBER(C12);D12<>0);" ";1);" ") 

Zistí či je vyplnené množstvo, alebo predmet. Vzorec si skopírujte po riadok 51.

L1=LARGE('číslo objednávky'.A2:A500;1) - posledné číslo objednávky.

L2=L1+1 - posledné číslo objednávky +1.

L3=LARGE('číslo objednávky'.B2:B500;1) - posledné číslo cenovej ponuky.

L4=L3+1 - posledné číslo cenovej ponuky + 1.

N1=IF(ISNUMBER(VLOOKUP(L2;'číslo objednávky'.A1:A500;1;0));1;0) 

Záznam je uložený, alebo nie.

N12=IF(AND(F12<>0;ISNUMBER(I12));ROUND(F12*I12;2);0)

Výpočet zľavy, vzorec prekopírovať až po riadok 51.

N52=SUM(N12:N51) - súčet zľavy.

O2=SUM(S12:S51) - súčet najnižšej ceny.

O4=IF(ISERROR(O2/H52-1);" ";(O2/H52-1)*-1) – najvyššia možná zľava za celú objednávku (celkovo).

O6=SUM(T12:T51) – réžia + práca celkom.

O12:O51 – v týchto bunkách je uvedené percento réžie pre každú položku, bunky sú podmieneným formátovaním upravené tak, že hodnota sa zviditeľní, až keď sú v riadku nejaké dáta.

P12=IF(ISERROR(VLOOKUP(B12;kód.$B$2:$H$1001;7;0));0;VLOOKUP(B12;kód.$B$2:$H$1001;7;0)+VLOOKUP(B12;kód.$B$2:$G$1001;6;0)*O12) 

Najnižšia možná cena za položku.

Q12=IF(ISERROR(C12/P12-1);0;C12/P12-1) – najvyššia možná zľava za položku.

R12=C12-N12 – cena za položku po zľave.

S12=P12*D12 – najnižšia cena za položku x množstvo.

T12=IF(ISERROR(VLOOKUP(B12;kód.$B$2:$G$1001;6;0));0;VLOOKUP(B12;kód.$B$2:$G$1001;6;0)+VLOOKUP(B12;kód.$B$2:$G$1001;6;0)*O12*D12) 

Réžia + práca za položku x množstvo.

U12=IF(ISERROR(VLOOKUP(B12;kalkulácia.$A$1:$BF$1000;57;0)*D12);0;(VLOOKUP(B12;kalkulácia.$A$1:$BF$1000;57;0)*D12)) 

Váha za položku x množstvo.

V12=IF(ISERROR(VLOOKUP(B12;kalkulácia.A1:BF1000;58;0));0;VLOOKUP(B12;kalkulácia.A1:BF1000;58;0)) 

Plocha za riadok. Riadok od P12 po V12 si označte a vzorce skopírujte po riadok 51. O58 – tu je vložený konverzný kurz. Takže to by bolo zo vzorcov v liste objednávka všetko. Ako ste si isto všimli, zostali nám ešte nejaké dáta v bunkách K1, M1, M2. Toto sú bunky spojené s ovládacími prvkami zaškrtávacie polia a rolovacie tlačítko.

Teraz si vložte do listu všetky ovládacie prvky. Postupujte tak ako vo faktúre ( OpenOffice.org vo výrobnej firme 2 – Faktúra 1). Zapnite si na paneli ovládacie prvky formulára – návrh formulára a vložte tlačidlá export do pdf, uložiť do databázy, prezrieť list výroby, tlačiť, +list výroby, len list výroby a nový. Upravte si ich (farba, veľkosť, pozícia). S makrami ich prepojíte neskôr.

Teraz si vložte zaškrtávacie polia objednávka a ponuka a taktiež si ich upravte. Rozdiel oproti zaškrtávacím poliam z faktúry je v tom, že obe sú prepojené s tou istou bunkou M2 a majú zadanú referenčnú hodnotu. Zaškrtávacie políčko objednávka má zapnutú hodnotu - 1 a vypnutú hodnotu - 2. Zaškrtávacie políčko ponuka to má naopak zapnutá - 2 vypnutá – 1. Týmto zabezpečíte to, že obe polia spolupracujú. Ak je zaškrtnuté jedno, odznačí sa druhé a naopak a hodnota v bunke M2 sa mení podľa toho, ktoré pole je zaškrtnuté (1,2).

Nastavenie zaškrtávacieho poľa objednávkaNastavenie zaškrtávacieho poľa objednávka

Nastavenie zaškrtávacieho poľa ponukaNastavenie zaškrtávacieho poľa ponuka

Na základe hodnoty v bunke M2 sa vám potom zmení aj výsledok vzorca v bunke C1, takže nápis.

Ďalej si vložte zaškrtávacie pole zľava, ktoré je prepojené s bunkou M1, no nemá uvedenú žiadnu referenčnú hodnotu, takže pri zaškrtnutí sa vám v bunke M1 objaví nápis PRAVDA. Na základe hodnoty v tejto bunke dostanete výsledok výpočtu vo vzorcoch v bunkách I12:I51 (zobrazenie buniek so zľavou).

Teraz si vložte ovládací prvok rolovacie tlačidlo, kde ho na karte dáta prepojte s bunkou K1. Na karte Všeobecné nastavte zvýšiť/znížiť hodnotu na 1 a opakovať áno podľa nasledovného obrázku.

Rolovacie tlačidlo nastavenieRolovacie tlačidlo nastavenie

V bunke K1 sa vám pri tlačení šípky na rolovacom tlačidle bude meniť hodnota, a to o 1 nahor, alebo nadol. Podľa hodnoty v tejto bunke je zistené % zľavy v bunkách I12:I51.

Ak máte všetko vložené, vypnite návrh formulára a vyskúšajte ovládacie prvky, či vám menia hodnoty v prepojených bunkách podľa nastavenia.

Formátovanie

Najskôr si označte celý list (v ľavom rohu kde sa stretávajú riadky so stĺpcami) a vyberte v kontextovom menu Formát buniek na karte Ochrana bunky možnosť Skryť vzorec. Chránené zatiaľ nechať nezaškrtnuté. (Kontextovú ponuku vyvolajte na niektorej z označených buniek.)

Zamknutie buniek: Zásada je taká, že buniek, do ktorých budete zapisovať, a bunky, ktoré sa menia pomocou ovládacích prvkov, nechať odomknuté, ostatné nechať chránené. Keďže východzie nastavenie Calcu je, že sú bunky chránené, odomknite len bunky podľa vyššie uvedeného. Odomknuté bunky: C5:C7,F4,B12:E51,B54,B57,K1,L1,L3,M1,M2,N1,O12:O51.

Pokiaľ zamknete list a budete chcieť meniť dáta v chránených bunkách, Calc vás na to upozorní, takže zistíte, ktorú bunku ste zabudli odomknúť. Teraz si označte stĺpce K:N a skryte ich. Nakoniec si ešte okno rozdeľte ako vo faktúre (OpenOffice.org vo výrobnej firme 3 – Faktúra 2), zamknite list a uložte dokument.

Nabudúce sa venujeme ďalším listom v objednávke.

(Jako ve škole) Průměr: 1,00 | Hodnotilo: 16
 

Přidat názor

 

Nejsou podporovány žádné značky, komentáře jsou jen čistě textové. Více o diskuzích najdete v nápovědě. Diskuzi můžete sledovat pomocí RSS kanálu.

 
Miroslav Gešvantner

Miroslav Gešvantner

 
 
 
woo jaw demo hz